GPU インスタンシング対応シェーダーの作成

このページでは、カスタムの Unity シェーダーに GPU インスタンシングのサポートを追加する方法について説明します。まず、カスタム Unity シェーダーが GPU インスタンシングをサポートするために必要とする、シェーダーキーワード、変数、および関数について説明します。その上で、サーフェスシェーダーと頂点/フラグメントシェーダーの両方にインスタンスごとのデータを追加する方法を示すサンプルを記載しています。

レンダーパイプラインの互換性

シェーダーの修正

このセクションには、GPU インスタンシングに関連する、シェーダーの追加についての情報が記載されています。

インスタンスごとのプロパティを複数使用する場合、MaterialPropertyBlock オブジェクトにその全てを記入する必要はありません。また、プロパティが欠落したインスタンスがある場合、Unity は、参照されているマテリアルからデフォルト値を取得します。マテリアルにそのプロパティのデフォルト値がない場合、Unity は値を 0 に設定します。インスタンシングされていないプロパティを MaterialPropertyBlock に入れるとインスタンシングが無効になるため、これは行わないでください。代わりに、それらのために別のマテリアルを作成してください。

Instancing_options スイッチ

[#pragma instancing_options](#pragma-instancing_options) ディレクティブは以下のスイッチを使用できます。

GPU インスタンシングでのシェーダーバリアントの使用

#pragma ディレクティブに noinstancing を指定しない限り、Unity はデフォルトで、インスタンシング バリアント を使用してサーフェスシェーダーを生成します。Unity はサーフェスシェーダーでは #pragma multi_compile_instancing の使用を無視します。

Unity のスタンダードシェーダーと StandardSpecular シェーダーは、デフォルトでインスタンシングをサポートしていますが、Transform 以外のインスタンスごとのプロパティを持っていません。

GPU インスタンシングが有効にされたゲームオブジェクトがシーンにない場合、Unity はインスタンシングシェーダーバリアントをストリッピングします。ストリッピングの挙動をオーバーライドするには以下を行ってください。

1. Project Settings (Edit > Project Settings) を開きます。
2. Graphics を開きます。
3. Shader Stripping セクションで、Instancing Variants を Keep All に設定します。

GPU インスタンシングシェーダーへのインスタンスごとのプロパティの追加

デフォルトでは、Unity は、インスタンス化されたドローコールごとに異なる Transform でゲームオブジェクトを GPU インスタンシングします。インスタンスにバリエーションを加えるには、シェーダーに変更を加えてインスタンスごとのプロパティ (色など) を追加します。これはサーフェスシェーダーと頂点/フラグメントシェーダーの両方で行うことができます。

カスタムシェーダーは、インスタンス単位のデータを必要としませんが、インスタンス ID は必要です (ワールドマトリックスが正しく機能するために必要なため)。サーフェスシェーダーは自動的にインスタンス ID を設定しますが、カスタムの頂点シェーダーとフラグメントシェーダーはそうではありません。カスタムの頂点シェーダーとフラグメントシェーダーで ID を設定するには、シェーダーの最初で UNITY_SETUP_INSTANCE_ID を使用します。この方法を示す例については、頂点シェーダーとフラグメントシェーダーの例 を参照してください。

インスタンス化されたプロパティを宣言すると、Unity は、ゲームオブジェクトに設定された MaterialPropertyBlock オブジェクトから全てのプロパティ値を 1 回のドローコールに集めます。MaterialPropertyBlock オブジェクトを使用してランタイムにインスタンスごとのデータを設定する方法の例については、ランタイムにインスタンスごとのデータを変更する例 を参照してください。

マルチパスシェーダーにインスタンス単位のデータを追加する場合は、以下の点に注意してください。

• マルチパスシェーダーに 2 つ以上のパスがある場合、Unity は最初のパスのみをインスタンス化します。なぜなら、Unity は後のパスをオブジェクトごとにまとめてレンダリングするため、マテリアルの変更が強制的に行われるからです。
• ビルトインレンダーパイプラインでフォワードレンダリングパスを使用する場合、Unity は、複数のライトの影響を受けるオブジェクトを効率的にインスタンス化できません。Unity は、ベースパスにのみインスタンシングを効果的に使用でき、追加パスには効果的に使用できません。ライティングパスについての詳細は、フォワードレンダリングとパスタグ のドキュメントを参照してください。

サーフェスシェーダーの例

以下の例は、インスタンスごとにカラー値が異なる、インスタンス化されたサーフェスシェーダーを作成する方法を示しています。

Shader "Custom/InstancedColorSurfaceShader"
{
    Properties
    {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200
        CGPROGRAM
        // Uses the physically based standard lighting model with shadows enabled for all light types.
        #pragma surface surf Standard fullforwardshadows
        // Use Shader model 3.0 target
        #pragma target 3.0
        sampler2D _MainTex;
        struct Input
        {
            float2 uv_MainTex;
        };
        half _Glossiness;
        half _Metallic;
        UNITY_INSTANCING_BUFFER_START(Props)
           UNITY_DEFINE_INSTANCED_PROP(fixed4, _Color)
        UNITY_INSTANCING_BUFFER_END(Props)
        void surf (Input IN, inout SurfaceOutputStandard o) {
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * UNITY_ACCESS_INSTANCED_PROP(Props, _Color);
            o.Albedo = c.rgb;
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

頂点シェーダーとフラグメントシェーダーの例

以下の例は、インスタンスごとにカラー値が異なる、インスタンス化された頂点/フラグメントシェーダーを作成する方法を示しています。サーフェスシェーダーと異なり、頂点シェーダーやフラグメントシェーダーを作成する時は、UNITY_SETUP_INSTANCE_ID を使用して手動でインスタンス ID を設定する必要があります。

Shader "Custom/SimplestInstancedShader"
{
    Properties
    {
        _Color ("Color", Color) = (1, 1, 1, 1)
    }

    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_instancing
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                UNITY_VERTEX_INPUT_INSTANCE_ID // use this to access instanced properties in the fragment shader.
            };

            UNITY_INSTANCING_BUFFER_START(Props)
                UNITY_DEFINE_INSTANCED_PROP(float4, _Color)
            UNITY_INSTANCING_BUFFER_END(Props)

            v2f vert(appdata v)
            {
                v2f o;

                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_TRANSFER_INSTANCE_ID(v, o);
                o.vertex = UnityObjectToClipPos(v.vertex);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                UNITY_SETUP_INSTANCE_ID(i);
                return UNITY_ACCESS_INSTANCED_PROP(Props, _Color);
            }
            ENDCG
        }
    }
}

ランタイムにインスタンスごとのデータを変更する例

以下の例は、MaterialPropertyBlock オブジェクトを使用してランタイムにゲームオブジェクトのグループにインスタンスごとのデータを設定する方法を示しています。これは、上記のシェーダーサンプルの _Color プロパティをランダムな色に設定します。

重要: MaterialPropertyBlock は SRP バッチャーの互換性を破ります。詳しくは GPU インスタンシング: 要件と互換性 を参照してください。

using UnityEngine;

public class MaterialPropertyBlockExample : MonoBehaviour
{
    public GameObject[] objects;

    void Start()
    {
        MaterialPropertyBlock props = new MaterialPropertyBlock();
        MeshRenderer renderer;

        foreach (GameObject obj in objects)
        {
            float r = Random.Range(0.0f, 1.0f);
            float g = Random.Range(0.0f, 1.0f);
            float b = Random.Range(0.0f, 1.0f);
            props.SetColor("_Color", new Color(r, g, b));

            renderer = obj.GetComponent<MeshRenderer>();
            renderer.SetPropertyBlock(props);
        }
    }
}