頂点プログラムへ頂点データの流し込み

Cg/HLSL 頂点プログラムに対し、メッシュの頂点データは頂点シェーダー関数への入力で渡されます。それぞれの入力には特定のセマンティックが必要です。例えば POSITION の入力は頂点の位置、そして NORMAL の入力は頂点の法線のデータです。

しばしば、頂点のデータ入力は 1 つずつ記述されず、構造体で宣言されます。よく使用される頂点構造体は、 UnityCG.cginc include ファイルで定義され、たいてい、それを使えば十分です。それらの構造体は以下の通りです。

appdata_base: 位置、法線および 1 つのテクスチャ座標で構成されます。
appdata_tan: 位置、接線、法線および 1 つのテクスチャ座標で構成されます。
appdata_full: 位置、接線、法線、4 つのテクスチャ座標および色で構成されています。

例: このシェーダーは、その法線に基づいて、メッシュに色を付け、頂点プログラム入力として、appdata_base を使用します。

Shader "VertexInputSimple" {
    SubShader {
        Pass {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
         
            struct v2f {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
            };
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color.xyz = v.normal * 0.5 + 0.5;
                o.color.w = 1.0;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target { return i.color; }
            ENDCG
        }
    } 
}

さまざまな頂点データにアクセスするには、頂点の構造体を自身で宣言するか、頂点シェーダーに入力パラメーターを加える必要があります。頂点のデータは Cg/HLSL セマンティックによって識別されます。そして、以下のリストに準ずる必要があります。

POSITION は頂点位置、一般的には float3 か float4 です。
NORMAL は通常の頂点で、一般的には float3 です。
TEXCOORD0 は、第 1 の UV 座標で、一般的に、float2, float3, float4 です。
TEXCOORD1, TEXCOORD2, TEXCOORD3 は、それぞれ第 2、第 3、第 4 の UV 座標です。
TANGENT は、（ノーマルマッピングで使用される）接線ベクトルで、一般的には、 float4 です。
COLOR は、頂点ごとの色で、一般的には、 float4 です。

メッシュデータが、頂点シェーダー入力で必要とされるよりも少ない数の要素しか持たない場合、デフォルトで 1 に設定されている .w 要素を除いて残りの部分をゼロで埋めます。例えば、メッシュテクスチャ座標は、しばしば、x と y コンポーネントしか持たない 2D ベクトルです。頂点シェーダーが TEXCOORD0 セマンティックで float4 の入力を宣言する場合、その頂点シェーダーによって受け取る値には (x,y,0,1) が含まれます。

例

UV の表示

次のシェーダーの例は、(構造体 appdata で定義された) 頂点シェーダー入力として、頂点位置と 1 つ目のテクスチャ座標を使用します。このシェーダーは、メッシュの UV 座標をデバッグするのに非常に便利です。

Shader "Debug/UV 1" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 頂点の入力: 位置、 UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord : TEXCOORD0;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

ここでは、UV 座標は、赤色と緑色で表示され、0 〜 1 の範囲外にある座標には、さらに青色が適用されます。

同様に、このシェーダーは、モデルの 2 つ目の UV を表示します。

Shader "Debug/UV 2" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 頂点の入力: 位置、 2つ目の UV
        struct appdata {
            float4 vertex : POSITION;
            float4 texcoord1 : TEXCOORD1;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.uv = float4( v.texcoord1.xy, 0, 0 );
            return o;
        }
        
        half4 frag( v2f i ) : SV_Target {
            half4 c = frac( i.uv );
            if (any(saturate(i.uv) - i.uv))
                c.b = 0.5;
            return c;
        }
        ENDCG
    }
}
}

頂点色の表示

次のシェーダーは、(構造体 appdata で定義された) 頂点シェーダー入力として、頂点位置と頂点ごとの色を使用します。

Shader "Debug/Vertex color" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 頂点の入力: 位置、 色
        struct appdata {
            float4 vertex : POSITION;
            fixed4 color : COLOR;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.color;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

色にベイクされた照明が設定されたトーラスノットモデルに適用されたカラーシェーダーをデバッグ

法線の表示

次のシェーダーは、(構造体 appdata で定義された) 頂点シェーダー入力として、頂点位置と法線を使用します。法線の X、Y、Z 成分は、RGB 色として表示されます。法線成分は、–1 から 1 の範囲なので、法線をスケールおよびバイアスし、出力される色は –1 から 1 の範囲で表示可能です。

Shader "Debug/Normals" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 頂点の入力: 位置、 法線
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color.xyz = v.normal * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

トーラスノットモデルに適用された法線シェーダーをデバッグ。モデルにハードシェーディングエッジがあるのが分かるでしょう。

接線と従法線の表示

接線および従法線ベクトルは、法線マッピングに使用されます。Unity では、接線ベクトルは、頂点に格納され、従法線ベクトルは、法線および接線から派生します。

次のシェーダーは、(構造体 appdata で定義された) 頂点シェーダー入力として、頂点位置と接線を使用します。接線の X、Y、Z 成分は、R、G、B 色として表示されます。法線成分は、–1 から 1 の範囲なので、それらを –1 から 1 の範囲でスケールおよびバイアスし、出力される色は –1 から 1 の範囲で表示可能です。

Shader "Debug/Tangents" {
SubShader {
    Pass {
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        // 頂点の入力: 位置、 接線
        struct appdata {
            float4 vertex : POSITION;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            fixed4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            o.color = v.tangent * 0.5 + 0.5;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

次のシェーダーでは、従接線が表示されています。頂点座標、法線そして接線の値が頂点入力として使われています。従接線(従法線とも呼ばれる)は法線と接線の値から計算されています。表示可能な 0 から 1 の範囲でスケールおよびバイアスされる必要があります。

Shader "Debug/Bitangents" {
SubShader {
    Pass {
        Fog { Mode Off }
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "UnityCG.cginc"

        //頂点の入力: 位置、法線、接線 
        struct appdata {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 tangent : TANGENT;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 color : COLOR;
        };
        
        v2f vert (appdata v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex );
            // bitangent を計算
            float3 bitangent = cross( v.normal, v.tangent.xyz ) * v.tangent.w;
            o.color.xyz = bitangent * 0.5 + 0.5;
            o.color.w = 1.0;
            return o;
        }
        
        fixed4 frag (v2f i) : SV_Target { return i.color; }
        ENDCG
    }
}
}

参考文書

Cg/HLSL でシェーダープロパティーを参照する

ビルトインのシェーダー include ファイル

"Unity"、Unity 徽标及其他 Unity 商标是 Unity Technologies 或其附属机构在美国及其他地区的商标或注册商标。其他名称或品牌是其各自所有者的商标。

公安部备案号:

31010902002961

法律条款隐私政策 Cookies