커스텀 URP 셰이더에서 그림자 사용

커스텀 URP(유니버설 렌더 파이프라인) 셰이더에서 그림자를 사용하려면 다음 과정을 따르십시오.

1. 셰이더 파일의 HLSLPROGRAM 안에 #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"을 추가합니다. Core.hlsl 파일은 Shadows.hlsl 및 RealtimeLights.hlsl 파일을 임포트합니다.
2. 다음 섹션의 메서드를 사용합니다.

그림자 공간의 위치 가져오기

다음 메서드를 사용하여 위치를 섀도우 맵 위치로 전환합니다.

그림자 계산

아래의 메서드들은 섀도우 맵을 사용하여 그림자를 계산합니다. 이러한 메서드를 사용하려면 먼저 아래의 과정을 수행하십시오.

1. 씬에 ShadowCaster 셰이더 패스가 있는 오브젝트(Universal Render Pipeline/Lit 셰이더를 사용하는 오브젝트 등)가 있는지 확인합니다.
2. 셰이더에 #pragma multi_compile _ _MAIN_LIGHT_SHADOWS _MAIN_LIGHT_SHADOWS_CASCADE _MAIN_LIGHT_SHADOWS_SCREEN을 추가하여 메인 광원에 대한 섀도우 맵에 액세스할 수 있게 합니다.
3. 셰이더에 #pragma multi_compile _ _ADDITIONAL_LIGHT_SHADOWS를 추가하여 추가 광원에 대한 섀도우 맵에 액세스할 수 있게 합니다.

예제

다음 URP 셰이더는 표면에 단순한 그림자를 드로우합니다.

그림자를 생성하려면 씬에 ShadowCaster 셰이더 패스가 있는 오브젝트(Universal Render Pipeline/Lit 셰이더를 사용하는 오브젝트 등)가 있는지 확인합니다.

Shader "Custom/SimpleShadows"
{
    SubShader
    {

        Tags { "RenderType" = "AlphaTest" "RenderPipeline" = "UniversalPipeline" }

        Pass
        {
            HLSLPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile _ _MAIN_LIGHT_SHADOWS _MAIN_LIGHT_SHADOWS_CASCADE _MAIN_LIGHT_SHADOWS_SCREEN

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

            struct Attributes
            {
                float4 positionOS  : POSITION;
            };

            struct Varyings
            {
                float4 positionCS  : SV_POSITION;
                float4 shadowCoords : TEXCOORD3;
            };

            Varyings vert(Attributes IN)
            {
                Varyings OUT;

                OUT.positionCS = TransformObjectToHClip(IN.positionOS.xyz);

                // Get the VertexPositionInputs for the vertex position  
                VertexPositionInputs positions = GetVertexPositionInputs(IN.positionOS.xyz);

                // Convert the vertex position to a position on the shadow map
                float4 shadowCoordinates = GetShadowCoord(positions);

                // Pass the shadow coordinates to the fragment shader
                OUT.shadowCoords = shadowCoordinates;

                return OUT;
            }

            half4 frag(Varyings IN) : SV_Target
            {
                // Get the value from the shadow map at the shadow coordinates
                half shadowAmount = MainLightRealtimeShadow(IN.shadowCoords);

                // Set the fragment color to the shadow value
                return shadowAmount;
            }
            
            ENDHLSL
        }
    }
}

추가 리소스

• 그림자
• URP의 그림자
• 커스텀 셰이더 작성
• URP 호환성을 위해 커스텀 셰이더 업그레이드
• Unity의 HLSL